Formatos utilizados en la reserva

From ABCD Wiki
Revision as of 14:32, 5 March 2015 by Guilda (talk | contribs) (Página creada con «{| class="wikitable" |- ! Nombre del formato !! Usado en |- | reserve_01.pft || Formato por defecto que provee ABCD para la presentación de las reservas. Se acompaña de '...»)
(diff) ← Older revision | Latest revision (diff) | Newer revision → (diff)
Jump to: navigation, search
Nombre del formato Usado en
reserve_01.pft Formato por defecto que provee ABCD para la presentación de las reservas. Se acompaña de tit_reserve_01.tab con los títulos de las columnas construídas por el formato
rsvr.pft Formato que provee el usuario para presentar las reservas. Si está presente sustitute al reserve_01.pft mencionado anteriormente. Se acompaña de rsvr_h.txt con los títulos de las columnas construídas por el formato
opac_rsvr.pft Formato que provee el usuario para presentar las reservas desde el iAH. Se acompaña de opac_rsvr_h.txt para nombrar las columnas generadas por el formato. Si este formato está ausente se usa rsvr.pft para presentar las reservas en el iAH
reserve_assigned.pft Se utiliza cuando se envía el correo avisando a un usuario que la reserva le ha sido asignada o cuando se solicita la impresión de los datos de la reserva asignada
tb_reserve.pft Se utiliza bajo la opción Base de datos -> Reserva para desplegar en forma de tabla los registros de la base de datos reserve (reservas). Se acompaña de tit_reserve.tab para darle nombre las columnas generadas por el formato

Ejemplo de los formatos de despliegue

Note que en estos formatos cada columna se genera agregando del delimitador | como literal incondicional. Además sólo se genera un salto de línea al final (/) para garantizar la separación entre registros.

El literal '#REFER#|' lo utiliza ABCD para determinar el lugar donde se debe insertar la referencia bibliográfica del objeto cuyo formato se obtiene a partir de la configuración del módulo de préstamos

reserve_01.pft

  
    v10,," ("v12")",'|'
    ref(['users']l(['users']'CO_'v10),v30,| <br><a href=mailto:|v160|>|v160|</a>)|),'|'  /*Nombre y correo*/
    v15,"-"v20,'|'
    '#REFER#|'
    v30*6.2,"-",v30*4.2,"-",v30.4 ,' ',v31'|'
    v60*6.2,"/"v60*4.2,"/"v60.4, " - "D40,
    if v1='0' or v1='3' then if p(v40) and v40<mid(date,0,8) then,
    '<font color=red>' fi,fi,v40*6.2,"/"v40*4.2,"/"v40.4'</font>|', 
    v200*6.2,"-",v200*4.2,"-",v200.4 ,'|' 
    v1/
    

tit_reserve_01.tab

   Código de usuario|Nombre|Número de control|Referencia|Fecha reserva|Fecha asignación|Fecha Préstamo|Sit.


rsvr.pft

    
     v10, " ("v12")",'|',                                                     /*Código/ tipo de usuario*/
     ref(['users']l(['users']'CO_'v10),
          v30,| (<a href=mailto:|v160|>|v160|)</a>)|),'|' ,                   /*Nombre y correo*/
     v15' - 'v20'|',                                                          /*BD y No.control objeto*/
     '#REFER#','|'                                                            /*Insertar referencia del objeto*/
     v30*6.2,"/"v30*4.2,"/"v30.4,' 'v31, '  'v32,'|'                          /*Fecha, hora, operador  que reserva*/
     if v1='0' or v1='3' then 
          if p(v40) and v40<mid(date,0,8) then,'<font color=red>' fi,
     fi, v60*6.2,"/"v60*4.2,"/"v60.4 '-', v40*6.2,"/"v40*4.2,"/"v40.4,'|',   /*Fecha desde-hasta espera*/
     v130*6.2,"/"v130*4.2,"/"v130.4'|',                                      /*Fecha de cancelación*/
     v200*6.2,"/"v200*4.2,"/"v200.4,'|',                                     /*Fecha asignación del préstamo*/
     v1/                                                                     /*Situación de la reserva*/
        

rsvr_h.txt

    Código de usuario
    Nombre
    Número de control
    Referencia
    Fecha reserva y Operador
    Lapso de espera
    Fecha cancelación
    Fecha préstamo
    Situación

opac_reserve.pft

  
   v15' - 'v20'|',                                                       /*BD y No. de control del objeto*/
   '#REFER#','|'                                                         /*Para insertar referencia bibliográfica*/
    v30*6.2,"/"v30*4.2,"/"v30.4,' 'v31, '  'v32,'|'                      /*Fecha, hora, operador de la reserva*/
    if v1='0' or v1='3' then if p(v40) and v40<mid(date,0,8) then,'<font color=red>' fi,
    fi, v60*6.2,"/"v60*4.2,"/"v60.4 '-', v40*6.2,"/"v40*4.2,"/"v40.4,'|',/*Fecha desde-hasta espera*/
    v130*6.2,"/"v130*4.2,"/"v130.4'|',                                   /*Fecha de cancelación de la reserva*/
    v200*6.2,"/"v200*4.2,"/"v200.4,'|',                                  /*Fecha en que se asignó el préstamo*/
    v1/                                                                  /*Situación*/
    

opac_reserve_h.txt

  Número de control
  Referencia
  Fecha reserva y Operador
  Lapso de espera
  Fecha cancelación
  Fecha préstamo
  Situación


reserve_assigned.pft

  
   '#FROM: reservas@msinfo.info#'/
   '#SUBJECT: Asignación de reserva#'/
   'Sr(a): ' ref(['users']l(['users']'CO_'v10),v30,,"#TO:"V160"#"),   /*Nombre y correo  El correo debe estar 
                                                                        precedido por #MAIL:  y terminar en #. 
                                                                        Solo se permite un correo*/
   '<br>Le ha sido asignada la reserva que tenía sobre el título<br>'
   '<p><b>#REFER#</b></font>'
   '<br>la cual estará vigente en lapso del '
   v60*6.2,"/"v60*4.2,"/"v60.4, " al "D40,v40*6.2,"/"v40*4.2,"/"v40.4 
   /
   


tb_reserve.pft

  
   f(mfn,1,0)'|'v1102'|'v1001'|'v1002'|',
   v10, " ("v12")",'|',                                                                /*Código y tipo de usuario*/
   ref(['users']l(['users']'CO_'v10),v30,| (<a href=mailto:|v160|>|v160|)</a>)|),'|' , /*Nombre y correo*/
   v15'|',                                                                             /*BD del objeto reservado */
   v20'|',                                                                             /*No.de control del objeto*/
   v30*6.2,"/"v30*4.2,"/"v30.4,'|'                                                     /*Fecha de la reserva*/
   v31'|',                                                                             /* Hora de la reserva*/
   v32,'|',                                                                            /*Operador que reserva*/
   v60*6.2,"/"v60*4.2,"/"v60.4 '|',                                                    /*Fecha asignación*/
   if v1='0' or v1='3' then 
      if p(v40) and v40<mid(date,0,8) then,'<font color=red>' fi fi,v40*6.2,"/"v40*4.2," 
      /"v40.4'|',                                                                      /*Fecha hasta espera*/
   v130*6.2,"/"v130*4.2,"/"v130.4'|',                                                  /*Fecha de cancelación*/
   v200*6.2,"/"v200*4.2,"/"v200.4,'|',                                                 /*Fecha de préstamo*/
   v1/                                                                                 /*Situación*/
   

tit_reserve.tab

  Código de usuario|
  Nombre|
  Base de datos|
  Número de control|
  Referencia|
  Fecha reserva|
  Operador|
  Lapso de espera|
  Fecha cancelación|
  Fecha préstamo|
  Situación